*  JieJie Microelectronics P-Spice Model Library
*  Filename:           JMSH040SAGQ_P v.20230424.txt
*  Product Name:       JMSH040SAGQ (PDFN5x6-8L)
*  Configuration:      Single N-channel Device
*  Data Sheet Rev.:    2.0
*  Release Date:       Apr25, 2023
*  Junction Temp (Tj): -40C ~ 175C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, Jiangsu JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH040SAGQ D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.00005
RS S 3 1E-006
RG G 17 2.5
CGS 3 G 2.01E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00503*(TEMP-25))+((-7.80422E-6)*(TEMP-25)^2)}
Gtemp 1 3  VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.9)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 4.2e-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cds D 3 Cbreak 1.0625E-8
.MODEL Cbreak CAP (C=1 VC1= -0.03319 VC2 = 3.23691E-4)

.model NMOS NMOS
+LEVEL = 3       
+VMAX = 8.544074E6           ETA = 3.468048E-5     
+VTO = 3.062221                TOX = 8E-10                   NSUB = 1E22                   
+KP = 463.561639               U0 = 400                      KAPPA = 0.125405              
+GAMMA = 0.088243              PHI = 1.22859                 THETA = 0.051655              
+DELTA = 147.430799            



.model DCGD D
+CJO = 1.81E-9                 VJ = 10                       M = 1.8     


.model DSUB D
+IS = 5.585231E-14             N = 0.971896                  RS = 1.122906E-3 
+BV = 48                      xti = 4.35134E-2              

.model DLIM D
+IS = 1E-4  
.ends JMSH040SAGQ

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************

